Dávkové soubory v praxi
Ujednání:
  • TEMP je proměnná nastavená v AUTOEXECu (např: SET TEMP=C:\RECYCLED) obsahující existující pracovní adresář.
  • Dávkové a pomocné TXT soubory jsou uloženy v adresáři C:\BATCH
  • Pozor na nechtěné zalomení textu na HTML stránce, baťák by pak nepracoval korektně.




  • EXTRACT.BAT
    Je výhodný pokud potřebujete rozbalit spoustu malých zazipovaných prográmků. Vytvářet ručně nové adresáře podle jména zipu, přesouvat je dovnitř, pak psát "unzip program.zip -d" protože "unzip *.zip -d" by rozbalilo i případný jiný zip uvnitř zazipovaného souboru je zbytečně pracné. (Otevřít zip přímo přes NC a zkopírovat ho ven zas občas blbne a hlavně změní datumy souborů.) Příkazová řádka je tu přece od toho aby zjednodušovala práci. Nepoužívat v DOSu baťáky je jako ovládat Windowsy klávesnicí a psát ve Wordu pomocí myši. Tenhle baťák vám zjednoduší práci na pouhé stisknutí ENTERu. Stačí nastavit v nějakém méně používaném "nortnu" např. VOLCOV COMMANDERu Extension file edit na: "zip: c:batch\extract.bat !". Je důležité napsat jen jeden otazník, jelikož baťák vyžaduje za parametr jen jméno souboru bez přípony zip.

    	@echo off
    	IF (%1)==() Goto NeniParametr
    	IF EXIST %1 Goto Duplicita
    	IF EXIST %1\*.* Goto Prepsani
    	md %1
    	move %1.zip %1\%1.zip
    	unzip %1\%1.zip %1\ -d
    	goto Exit
    	:Prepsani
    	echo Adresar se soubory uz existuje!
    	goto exit
    	:Duplicita
    	echo Byl nalezen soubor se stejnym jmenem jaky ma mit novy adresar!
    	goto exit
    	:NeniParametr
    	echo   Vstup: Jmeno ZIP souboru bez pripony.
    	echo  Vystup: Vytvori adresar, do neho presune ZIP soubor a rozbali ho.
    	echo.
    	echo Priklad: %0 soubor
    	:Exit
    	


    HTML.BAT
    Tak tenhle baťák se zase umí vrátit na původní adresář a to i z jiného disku. Bohužel příkaz ECHO automaticky "odentruje" na další řádek a tak se neobejdeme bez pomocného TXT souboru na adrese C:\BATCH\CD.TXT obsahujícího pouze 3 písmena a to: "CD ". Baťák prvně uloží aktuální adresu a pak i jméno disku do pomocných souboru, poté změní aktuální adresář k programu ARACHNE, který to vyžaduje (tuhle část si musíte upravit podle vlastní adresářové struktury). Spustí baťák ARACHNE.BAT s parametrem disk:\cesta\soubor.htm. Po jeho ukončení vrátí původní adresář a smaže pomocné soubory. Do NC si nastavte u Extension file edit pro HTM: "c:\batch\html.bat !:!\!.!"

    	@echo off
    	IF (%1)==() Goto NeniParametr
    
    	echo Ukladam aktualni adresu:
    	cd>%temp%\cesta.tmp
    	echo %temp%\cesta.tmp
    
    	echo Ukladam aktualni disk:
    	cd\
    	cd>%temp%\disk.bat
    	echo %temp%\disk.bat
    
    	rem Tuhle cast si upravte!!!
    	c:
    	cd c:\tools\arachne
    	call arachne.bat %1
    
    	echo Vracim puvodni disk
    	call %temp%\disk.bat
    
    	echo Vracim puvodni adresu
    	copy c:\batch\cd.txt + %temp%\cesta.tmp %temp%\return.bat >nul
    	call %temp%\return.bat
    
    	del %temp%\disk.bat
    	del %temp%\cesta.tmp
    	del %temp%\return.bat
    
    	goto Exit
    	:NeniParametr
    	echo   Vstup: Jmeno HTML souboru s cestou. (V NC !:!\!.!)
    	echo  Vystup: Presune se na adresar s programem ARACHNE a po ukonceni vrati zpet.
    	echo.
    	echo Priklad: %0 d:\html\soubor.htm
    	:Exit
    	


    Chcete vědět kolikrát jste zapnuli/restartovali počítač, v jakou dobu a s jakým nastavením? (máte-li rozvětvený config.sys) Pak stačí přidat tyto řádky do svého AUTOEXECu. Baťák vyžaduje pro svou činnost pomocný TXT soubor na adrese C\:BATCH\ENTER.TXT obsahující jen jeden znak a to "enter", kód 13.

    	echo ----------------- %CONFIG% -------------------- >>%temp%\login.txt
    	date <c:\batch\enter.txt >>%temp%\login.txt
    	time <c:\batch\enter.txt >>%temp%\login.txt
    	
    Pokud máte 486 a nižší počítač a jste v DOSu, měli byste se pro vlastní dobro naučit těch par příkazů dávkových souboru...